#include "llmod.as"
#include "calender.as"


title "今日の日付は、"+year+"年 "+month+"月 "+day+"日 です。"

x=10 : y=10 : i=month-1
repeat 3
	if i< 1 : i=12 : else : if i>12 : i=1

	font "ＭＳ 明朝",12

	//月を表示
	;--------------------------------------
	color   0,  0,  0 : boxf x,y,30*7+x,20+y
	color 255,255,255 : pos 30*7+x-5,y+5 : mes ""+i+"月",ALIGN_RIGHT
	y += 25

	font "ＭＳ 明朝",18

	objsize 30,20 ;<<-- カレンダーの１枠の大きさを指定

	//ランダムに日付に丸をつける
	;--------------------------------------
	sdim check,2,32
	if i == month {
		color 192,192,192 : randomize
		repeat 5 : rnd a,28 : check.a="●" : loop
		pos x,y-3 : calender check, year,i,ALIGN_CENTER
	}

	font "ＭＳ 明朝",12

	//今日の日付を太字にする
	;--------------------------------------
	sdim check,2,32
	if i == month {
		color 0,0,0 : check.day=""+day
		pos x-1,y : calender check, year,i,ALIGN_CENTER
	}

	//すべての日付の表示
	;--------------------------------------
	pos x,y : calender check, year,i,ALIGN_CENTER,1

	y += stat ;<<-- stat は、カレンダーの終わり位置の高さを返す

	color 0,0,0 : line x,y,30*7+x,y

	y += 5 : i++
loop

//応用編 (日付文字列の変更方法？)
;--------------------------------------
sdim check,5,32
check.1="一","二","三","四","五","六","七","八","九","十"
repeat 21,11
	i=cnt/10 : ii=cnt\10 : if ii=0 : ii=10
	check.cnt=""+check.i+""+check.ii
loop

x=250 : y=10

objsize 45,20 ;<<-- カレンダーの１枠の大きさを指定

//月を表示
color   0,  0,128 : boxf x,y,45*7+x,20+y
color 255,255,255 : pos 45*7+x-5,y+5 : mes ""+check.month+"月",ALIGN_RIGHT
y += 25

//今日の日付を ( ) で囲む
check.day="("+check.day+")"


//いざ、表示！！
color   0,  0,128 : pos x,y : calender check, year,month,ALIGN_RIGHT

stop